#!/bin/csh -f

set fullprogname = $0
set fullprogname = `echo $fullprogname | sed 's+^\([^/]\)+./\1+'`
set progdir = $fullprogname:h
set progname = $fullprogname:t

set wfreqtype = "`echo $progname | sed 's+wfreq++'`"

set tempscript = /tmp/${wfreqtype}wfreq.awk.$user.$$
set tempinput =  /tmp/${wfreqtype}wfreq.inp.$user.$$

if ($#argv < 1) then
  cat > $tempinput
else
  set tempinput = ""
endif

foreach file ($* $tempinput)

  set counts = `cat $file | ${wfreqtype}wc`

  echo \
'{wfreq[$1]++}\
 END {for (word in wfreq) { \
        printf "%s	%d", word, wfreq[word]' > $tempscript
  @ i = 1
  while( $i <= $#counts )
    echo '        printf "	%f", wfreq[word]/'$counts[$i] >> $tempscript
    @ i++
  end
  echo '        print ""}}' >> $tempscript

  cat $file \
    | ${wfreqtype}sepwordsdepunc \
    | ${wfreqtype}downcase \
    | h${wfreqtype}2e${wfreqtype} \
    | awk -f $tempscript \
    | e${wfreqtype}2h${wfreqtype} \
    | sort -nr +1 > $file.wf

end

if ("$tempinput" != "") cat $tempinput.wf

rm -f $tempscript $tempinput $tempinput.wf