#!/bin/csh -f

# Takes an argument list as for dvi2tty and prepends custom settings
# of the -e, -w, and -h options according to the typesize specified in
# the name by which this command is called.  (The command name is
# (dvi2ttyXpt, where X is any of 5, 6, 7, 8, 9, 10, 11, 12, 14, 17,
# 21, and 25.)  Assumes that the root name of the file is $1.

set fullprogname = $0
set fullprogname = `echo $fullprogname | sed 's+^\([^/]\)+./\1+'`
set progdir = $fullprogname:h
set progname = $fullprogname:t

echo "${progname}:  Input: $*   Output: $1.tty"

set ttywidth = 250
set espace = -125
set pageheight = 77

# Remember, if lines get squashed together, increase pageheight.  If
# characters on a line get squashed together, increase espace (i.e.,
# make it less negative).

switch ($0)
case *5pt:
  set espace = -20
  set pageheight = 170
  breaksw
case *6pt:
  set espace = -85
  set pageheight = 140
  breaksw
case *7pt:
  set espace = -90
  set pageheight = 120
  breaksw
case *8pt:
  set espace = -105
  set pageheight = 97
  breaksw
case *9pt:
  set espace = -115
  set pageheight = 90
  breaksw
case *10pt:
  breaksw
case *11pt:
  set espace = -134
  set pageheight = 66
  breaksw
case *12pt:
  set espace = -144
  set pageheight = 65
  breaksw
case *14pt:
  set espace = -160
  set pageheight = 50
  breaksw
case *17pt:
  set espace = -168
  set pageheight = 43
  breaksw
case *21pt:
  set espace = -175
  set pageheight = 37
  breaksw
case *25pt:
  set espace = -185
  set pageheight = 32
  breaksw
endsw

dvi2tty -w $ttywidth -e $espace -h $pageheight $* > $1.tty